/[ascend]/trunk/nsis/installer.nsi
ViewVC logotype

Contents of /trunk/nsis/installer.nsi

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1572 - (show annotations) (download)
Sat Aug 4 07:53:42 2007 UTC (11 years, 11 months ago) by jpye
File size: 16655 byte(s)
Documentation is now included with the installer on Windows.
1 ; NSIS script to create an ASCEND binary installer for Windows
2 ; by John Pye, 2006-2007.
3 ;
4 ;--------------------------------
5
6 ; The name of the installer
7
8 !ifndef VERSION
9 !define VERSION 0.svn
10 !endif
11
12 Name "ASCEND ${VERSION}"
13
14 ;SetCompressor /FINAL zlib
15 SetCompressor /SOLID lzma
16
17 !include LogicLib.nsh
18 !include nsDialogs.nsh
19
20 !ifndef PYVERSION
21 !define PYVERSION "2.5"
22 !endif
23
24 !ifndef PYPATCH
25 !define PYPATCH ".1"
26 !endif
27
28 ; The file to write
29 !ifdef OUTFILE
30 OutFile ${OUTFILE}
31 !else
32 OutFile "ascend-${VERSION}-py${PYVERSION}.exe"
33 !endif
34
35
36 ; The default installation directory
37 InstallDir $PROGRAMFILES\ASCEND
38
39 ; Registry key to check for directory (so if you install again, it will
40 ; overwrite the old one automatically)
41 InstallDirRegKey HKLM "Software\ASCEND" "Install_Dir"
42
43 ;--------------------------------
44
45 ; Pages
46
47 Page license
48 LicenseData "..\LICENSE.txt"
49
50 Page components
51 Page directory
52 Page custom dependenciesCreate dependenciesLeave
53 Page instfiles
54 Page custom ascendIniCreate ascendIniLeave
55
56 UninstPage uninstConfirm
57 UninstPage instfiles
58
59 ;--------------------------------
60
61 Var /GLOBAL DEFAULTPATH
62 Var /GLOBAL PYOK
63 Var /GLOBAL PYPATH
64 Var /GLOBAL GTKOK
65 Var /GLOBAL GTKPATH
66 Var /GLOBAL GLADEOK
67 Var /GLOBAL PYGTKOK
68 Var /GLOBAL PYGOBJECTOK
69 Var /GLOBAL PYCAIROOK
70 Var /GLOBAL GLADEPATH
71 Var /GLOBAL PYINSTALLED
72 Var /GLOBAL TCLOK
73 Var /GLOBAL TCLPATH
74 Var /GLOBAL TCLINSTALLED
75
76 Var /GLOBAL PDFINSTALLED
77
78 Var /GLOBAL PATH
79
80 Var /GLOBAL PYDOWNLOAD
81 Var /GLOBAL PYGTKDOWNLOAD
82 Var /GLOBAL PYGOBJECTDOWNLOAD
83 Var /GLOBAL PYCAIRODOWNLOAD
84 Var /GLOBAL GTKDOWNLOAD
85
86 Var /GLOBAL ASCENDINIFOUND
87
88 Function .onInit
89 StrCpy $PYINSTALLED ""
90 StrCpy $TCLINSTALLED ""
91 StrCpy $ASCENDINIFOUND ""
92 StrCpy $PDFINSTALLED ""
93
94 ExpandEnvStrings $DEFAULTPATH "%WINDIR%;%WINDIR%\system32"
95
96 Call DetectPython
97 Pop $PYOK
98 Pop $PYPATH
99
100 Call DetectGTK
101 Pop $GTKOK
102 Pop $GTKPATH
103
104 Call DetectGlade
105 Pop $GLADEOK
106 Pop $GLADEPATH
107
108 Call DetectTcl
109 Pop $TCLOK
110 Pop $TCLPATH
111
112 Call DetectPyGTK
113 Pop $PYGTKOK
114
115 Call DetectPyGObject
116 Pop $PYGOBJECTOK
117
118 Call DetectPyCairo
119 Pop $PYCAIROOK
120
121 StrCpy $PATH "$DEFAULTPATH;$PYPATH;$GTKPATH"
122
123 FunctionEnd
124
125 ;------------------------------------------------------------
126 ; DOWNLOAD AND INSTALL DEPENDENCIES FIRST
127
128 !define PYTHON_VERSION "${PYVERSION}${PYPATCH}"
129 !define PYTHON_FN "python-${PYTHON_VERSION}.msi"
130 !define PYTHON_URL "http://www.python.org/ftp/python/${PYTHON_VERSION}/${PYTHON_FN}"
131 !define PYTHON_CMD "msiexec /i $DAI_TMPFILE /passive"
132
133 !define GTK_FN "gtk-2.10.11-win32-1.exe"
134 !define GTK_URL "http://downloads.sourceforge.net/gladewin32/${GTK_FN}"
135 !define GTK_CMD "$DAI_TMPFILE"
136
137 !define PYGOBJECT_FN "pygobject-2.12.3-1.win32-py${PYVERSION}.exe"
138 !define PYGOBJECT_URL "http://ftp.gnome.org/pub/GNOME/binaries/win32/pygobject/2.12/${PYGOBJECT_FN}"
139 !define PYGOBJECT_CMD "$DAI_TMPFILE"
140
141 !define PYCAIRO_FN "pycairo-1.2.6-1.win32-py${PYVERSION}.exe"
142 !define PYCAIRO_URL "http://ftp.gnome.org/pub/GNOME/binaries/win32/pycairo/1.2/${PYCAIRO_FN}"
143 !define PYCAIRO_CMD "$DAI_TMPFILE"
144
145 !define PYGTK_FN "pygtk-2.10.4-1.win32-py${PYVERSION}.exe"
146 !define PYGTK_URL "http://ftp.gnome.org/pub/GNOME/binaries/win32/pygtk/2.10/${PYGTK_FN}"
147 !define PYGTK_CMD "$DAI_TMPFILE"
148
149 !include "download.nsi"
150
151 Section "-python"
152 DetailPrint "--- DOWNLOAD PYTHON ---"
153 ${If} $PYDOWNLOAD == '1'
154 !insertmacro downloadAndInstall "Python" "${PYTHON_URL}" "${PYTHON_FN}" "${PYTHON_CMD}"
155 Call DetectPython
156 Pop $PYOK
157 Pop $PYPATH
158 ${If} $PYOK == 'NOK'
159 MessageBox MB_OK "Python installation appears to have failed"
160 ${EndIf}
161 ${EndIf}
162 SectionEnd
163 Section "-gtk"
164 DetailPrint "--- DOWNLOAD GTK+ ---"
165 ${If} $GTKDOWNLOAD == '1'
166 !insertmacro downloadAndInstall "GTK+" ${GTK_URL} ${GTK_FN} ${GTK_CMD}
167 Call DetectGTK
168 Pop $GTKOK
169 Pop $GTKPATH
170 Call DetectGlade
171 Pop $GLADEOK
172 Pop $GLADEPATH
173 ${EndIf}
174 SectionEnd
175 Section "-pygobject"
176 DetailPrint "--- DOWNLOAD PYGOBJECT ---"
177 ${If} $PYGOBJECTDOWNLOAD == '1'
178 ${AndIf} $PYOK == 'OK'
179 !insertmacro downloadAndInstall "PyGObject" ${PYGOBJECT_URL} ${PYGOBJECT_FN} ${PYGOBJECT_CMD}
180 Call DetectPyGObject
181 Pop $PYGOBJECTOK
182 ${EndIf}
183 SectionEnd
184 Section "-pycairo"
185 DetailPrint "--- DOWNLOAD PYCAIRO ---"
186 ${If} $PYCAIRODOWNLOAD == '1'
187 ${AndIf} $PYOK == 'OK'
188 !insertmacro downloadAndInstall "PyCairo" ${PYCAIRO_URL} ${PYCAIRO_FN} ${PYCAIRO_CMD}
189 Call DetectPyCairo
190 Pop $PYCAIROOK
191 ${EndIf}
192 SectionEnd
193 Section "-pygtk"
194 DetailPrint "--- DOWNLOAD PYGTK ---"
195 ${If} $PYGTKDOWNLOAD == '1'
196 ${AndIf} $PYOK == 'OK'
197 !insertmacro downloadAndInstall "PyGTK" ${PYGTK_URL} ${PYGTK_FN} ${PYGTK_CMD}
198 Call DetectPyGTK
199 Pop $PYGTKOK
200
201 ${EndIf}
202 SectionEnd
203
204 ;------------------------------------------------------------------------
205 ; INSTALL CORE STUFF including model library
206
207 ; The stuff to install
208 Section "ASCEND (required)"
209 SectionIn RO
210
211 DetailPrint "--- COMMON FILES ---"
212
213 ; Set output path to the installation directory.
214 SetOutPath $INSTDIR
215 File "..\ascend.dll"
216 File "..\ascend-config"
217 File "..\pygtk\glade\ascend.ico"
218 File "..\LICENSE.txt"
219 File "..\CHANGELOG.txt"
220 File "..\README-windows.txt"
221
222 ; Model Library
223 SetOutPath $INSTDIR\models
224 File /r /x .svn "..\models\*.a4*"
225 File /r /x .svn "..\models\*.tcl"
226 File /r /x .svn "..\models\*.dll" ; extension modules
227 File /r /x .svn "..\models\*.py"; python modules
228
229 SetOutPath $INSTDIR\solvers
230 File "..\solvers\qrslv\qrslv.dll"
231 File "..\solvers\conopt\conopt.dll"
232 File "..\solvers\lrslv\lrslv.dll"
233 File "..\solvers\cmslv\cmslv.dll"
234 File "..\solvers\lsode\lsode.dll"
235 File "..\solvers\ida\ida.dll"
236
237 SetOutPath $INSTDIR
238 ;File "Makefile.bt"
239 File "..\tools\textpad\ascend.syn"
240
241 ${If} ${FileExists} "$APPDATA\.ascend.ini"
242 StrCpy $ASCENDINIFOUND "1"
243 ${Else}
244 ; Set 'librarypath' in .ascend.ini
245 WriteINIstr $APPDATA\.ascend.ini Directories librarypath "$DOCUMENTS\ascdata;$INSTDIR\models"
246 ${EndIf}
247
248 ; Write the installation path into the registry
249 WriteRegStr HKLM SOFTWARE\ASCEND "Install_Dir" "$INSTDIR"
250
251 ; Write the uninstall keys for Windows
252 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ASCEND" "DisplayName" "ASCEND Simulation Environment"
253 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ASCEND" "UninstallString" '"$INSTDIR\uninstall.exe"'
254 WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ASCEND" "NoModify" 1
255 WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ASCEND" "NoRepair" 1
256 WriteUninstaller "uninstall.exe"
257
258 ; Write file locations to the registry for access from ascend-config
259 WriteRegStr HKLM SOFTWARE\ASCEND "INSTALL_LIB" "$INSTDIR"
260 WriteRegStr HKLM SOFTWARE\ASCEND "INSTALL_BIN" "$INSTDIR"
261 WriteRegStr HKLM SOFTWARE\ASCEND "INSTALL_INCLUDE" "$INSTDIR\include"
262 WriteRegStr HKLM SOFTWARE\ASCEND "INSTALL_ASCDATA" "$INSTDIR"
263 WriteRegStr HKLM SOFTWARE\ASCEND "INSTALL_MODELS" "$INSTDIR\models"
264 WriteRegStr HKLM SOFTWARE\ASCEND "INSTALL_SOLVERS" "$INSTDIR\solvers"
265 WriteRegStr HKLM SOFTWARE\ASCEND "GTKLIBS" "$GTKPATH"
266
267 ; Create 'ascend-config.bat' batch file for launching the python script 'ascend-config'.
268 ClearErrors
269 FileOpen $0 $INSTDIR\ascend-config.bat w
270 IfErrors ascendconfigerror
271 FileWrite $0 "@echo off"
272 FileWriteByte $0 "13"
273 FileWriteByte $0 "10"
274 FileWrite $0 "set PATH=$PATH"
275 FileWriteByte $0 "13"
276 FileWriteByte $0 "10"
277 FileWrite $0 "cd "
278 FileWrite $0 $INSTDIR
279 FileWriteByte $0 "13"
280 FileWriteByte $0 "10"
281 FileWrite $0 "$PYPATH\python "
282 FileWriteByte $0 "34"
283 FileWrite $0 "$INSTDIR\ascend-config"
284 FileWriteByte $0 "34"
285 FileWrite $0 " %1 %2 %3 %4 %5 %6 %7 %8"
286 FileWriteByte $0 "13"
287 FileWriteByte $0 "10"
288
289 FileClose $0
290
291 Return
292 ascendconfigerror:
293 MessageBox MB_OK "The 'ascend-config.bat' file was not installed properly; problems writing to that file."
294
295 SectionEnd
296
297 ;--------------------------------
298
299 Section "PyGTK GUI"
300 ; Check the dependencies of the PyGTK GUI before proceding...
301 ${If} $PYOK == 'NOK'
302 MessageBox MB_OK "PyGTK GUI can not be installed, because Python was not found on this system.$\nIf you do want to use the PyGTK GUI, please check the installation instructions$\n$\n(PYPATH=$PYPATH)"
303 ${ElseIf} $GTKOK == 'NOK'
304 MessageBox MB_OK "PyGTK GUI cannot be installed, because GTK+ 2.x was not found on this system.$\nIf you do want to use the PyGTK GUI, please check the installation instructions$\n$\n(GTKPATH=$GTKPATH)"
305 ${ElseIf} $GLADEOK == 'NOK'
306 MessageBox MB_OK "PyGTK GUI cannot be installed, because Glade 2.x was not found on this system.$\nIf you do want to use the PyGTK GUI, please check the installation instructions$\n$\n(GTKPATH=$GTKPATH).\n\nIf you do have GTK+ runtime installed, make sure\nyou have a version that includes support for Glade."
307 ${ElseIf} $PYGTKOK == "NOK"
308 MessageBox MB_OK "PyGTK GUI cannot be installed, because PyGTK was not found on this system.$\nPlease check the installation instructions.$\n$\n(PYPATH=$PYPATH)"
309 ${ElseIf} $PYCAIROOK == "NOK"
310 MessageBox MB_OK "PyGTK GUI cannot be installed, because PyCairo was not found on this system.$\nPlease check the installation instructions.$\n$\n(PYPATH=$PYPATH)"
311 ${ElseIf} $PYGOBJECTOK == "NOK"
312 MessageBox MB_OK "PyGTK GUI cannot be installed, because PyGObject was not found on this system.$\nPlease check the installation instructions.$\n$\n(PYPATH=$PYPATH)"
313 ${Else}
314 ;MessageBox MB_OK "Python: $PYPATH, GTK: $GTKPATH"
315
316 DetailPrint "--- PYTHON INTERFACE ---"
317
318 ; Set output path to the installation directory.
319 SetOutPath $INSTDIR
320
321 ; Python interface
322 File /nonfatal "..\pygtk\_ascpy.pyd"
323 File "..\pygtk\*.py"
324 File "..\pygtk\ascend"
325 File "..\pygtk\glade\ascend-doc.ico"
326
327 SetOutPath $INSTDIR\glade
328 File "..\pygtk\glade\*.glade"
329 File "..\pygtk\glade\*.png"
330 File "..\pygtk\glade\*.svg"
331
332 StrCpy $PYINSTALLED "1"
333 WriteRegDWORD HKLM "SOFTWARE\ASCEND" "Python" 1
334
335 ;---- file association ----
336
337 ; back up old value of .a4c file association
338 ReadRegStr $1 HKCR ".a4c" ""
339 StrCmp $1 "" a4cnobkp
340 StrCmp $1 "ASCEND.model" a4cnobkp
341
342 ; Remember the old file association if necessary
343 WriteRegStr HKLM "SOFTWARE\ASCEND" "BackupAssocA4C" $1
344
345 a4cnobkp:
346 WriteRegStr HKCR ".a4c" "" "ASCEND.model"
347
348 ; back up old value of .a4c file association
349 ReadRegStr $1 HKCR ".a4l" ""
350 StrCmp $1 "" a4lnobkp
351 StrCmp $1 "ASCEND.model" a4lnobkp
352
353 ; Remember the old file association if necessary
354 WriteRegStr HKLM "SOFTWARE\ASCEND" "BackupAssocA4L" $1
355
356 a4lnobkp:
357 WriteRegStr HKCR ".a4l" "" "ASCEND.model"
358
359 ; So, what does an A4L or A4C file actually do?
360
361 ReadRegStr $0 HKCR "ASCEND.model" ""
362 StrCmp $0 "" 0 a4cskip
363
364 WriteRegStr HKCR "ASCEND.model" "" "ASCEND model file"
365 WriteRegStr HKCR "ASCEND.model\shell" "" "open"
366 WriteRegStr HKCR "ASCEND.model\DefaultIcon" "" "$INSTDIR\ascend-doc.ico"
367
368 a4cskip:
369 WriteRegStr HKCR "ASCEND.model\shell\open\command" "" '$PYPATH\pythonw "$INSTDIR\ascend" "%1"'
370
371 System::Call 'Shell32::SHChangeNotify(i 0x8000000, i 0, i 0, i 0)'
372
373 ${EndIf}
374 Return
375
376 SectionEnd
377
378 ;---------------------------------
379
380 Section "Tcl/Tk GUI"
381
382 ${If} $TCLOK != 'OK'
383 MessageBox MB_OK "Tck/Tk GUI can not be installed, because ActiveTcl was not found on this system. If do you want to use the Tcl/Tk GUI, please check the installation instructions ($TCLPATH)"
384 ${Else}
385 DetailPrint "--- TCL/TK INTERFACE ---"
386 SetOutPath $INSTDIR\tcltk
387 File /r /x .svn "..\tcltk\TK\*"
388 SetOutPath $INSTDIR
389 File "..\tcltk\generic\interface\ascendtcl.dll"
390 File "..\tcltk\generic\interface\ascend4.exe"
391
392 StrCpy $TCLINSTALLED "1"
393 WriteRegDWORD HKLM "SOFTWARE\ASCEND" "TclTk" 1
394
395 ${EndIf}
396
397 SectionEnd
398
399 ;---------------------------------
400
401 Section "Documentation"
402 SetOutPath $INSTDIR
403 File "..\doc\book.pdf"
404 StrCpy $PDFINSTALLED "1"
405 WriteRegDWORD HKLM "SOFTWARE\ASCEND" "PDF" 1
406 SectionEnd
407
408 ; Optional section (can be disabled by the user)
409 Section "Start Menu Shortcuts"
410
411 WriteRegDWORD HKLM "SOFTWARE\ASCEND" "StartMenu" 1
412
413 CreateDirectory "$SMPROGRAMS\ASCEND"
414
415 ; Link to PyGTK GUI
416 ${If} $PYINSTALLED == "1"
417 CreateShortCut "$SMPROGRAMS\ASCEND\ASCEND.lnk" "$PYPATH\pythonw.exe" '"$INSTDIR\ascend"' "$INSTDIR\ascend.ico" 0
418 ${EndIf}
419
420 ; Model library shortcut
421 CreateShortCut "$SMPROGRAMS\ASCEND\Model Library.lnk" "$INSTDIR\models" "" "$INSTDIR\models" 0
422
423 ; Link to Tcl/Tk GUI
424 ${If} $TCLINSTALLED == "1"
425 CreateShortCut "$SMPROGRAMS\ASCEND\ASCEND Tcl/Tk.lnk" "$INSTDIR\ascend4.exe" "" "$INSTDIR\ascend4.exe" 0
426 ${EndIf}
427
428 ; Documentation
429 ${If} $PDFINSTALLED == "1"
430 CreateShortCut "$SMPROGRAMS\ASCEND\User's Manual.lnk" "$INSTDIR\book.pdf" "" "$INSTDIR\book.pdf" 0
431 ${EndIf}
432
433 ; Information files
434 CreateShortCut "$SMPROGRAMS\ASCEND\LICENSE.lnk" "$INSTDIR\LICENSE.txt" '' "$INSTDIR\LICENSE.txt" 0
435 CreateShortCut "$SMPROGRAMS\ASCEND\CHANGELOG.lnk" "$INSTDIR\CHANGELOG.txt" '' "$INSTDIR\CHANGELOG.txt" 0
436 CreateShortCut "$SMPROGRAMS\ASCEND\README.lnk" "$INSTDIR\README-windows.txt" '' "$INSTDIR\README-windows.txt" 0
437
438 CreateShortCut "$SMPROGRAMS\ASCEND\Uninstall.lnk" "$INSTDIR\uninstall.exe" "" "$INSTDIR\uninstall.exe" 0
439
440 SectionEnd
441
442 ;------------------------------------------------------------------
443 ; UNINSTALLER
444
445 Section "Uninstall"
446
447 ;--- python components ---
448
449 ReadRegDWORD $0 HKLM "SOFTWARE\ASCEND" "Python"
450 IntCmp $0 0 unnopython unpython
451
452 unpython:
453 DetailPrint "--- REMOVING PYTHON COMPONENTS ---"
454 Delete $INSTDIR\_ascpy.pyd
455 Delete $INSTDIR\ascend
456 Delete $INSTDIR\*.py
457 Delete $INSTDIR\*.pyc
458 Delete $INSTDIR\glade\*.glade
459 Delete $INSTDIR\glade\*.png
460 Delete $INSTDIR\glade\*.svg
461 RmDir $INSTDIR\glade
462 Delete $INSTDIR\ascend-doc.ico
463
464 ;--- file association (for Python GUI) ---
465
466 DetailPrint "--- REMOVING FILE ASSOCIATION ---"
467 ;start of restore script
468 ReadRegStr $1 HKCR ".a4c" ""
469 ${If} $1 == "ASCEND.model"
470 ReadRegStr $1 HKLM "SOFTWARE\ASCEND" "BackupAssocA4C"
471 ${If} $1 == ""
472 ; nothing to restore: delete it
473 DeleteRegKey HKCR ".a4c"
474 ${Else}
475 WriteRegStr HKCR ".a4c" "" $1
476 ${EndIf}
477 DeleteRegValue HKLM "SOFTWARE\ASCEND" "BackupAssocA4C"
478 ${EndIf}
479
480 ReadRegStr $1 HKCR ".a4l" ""
481 ${If} $1 == "ASCEND.model"
482 ReadRegStr $1 HKLM "SOFTWARE\ASCEND" "BackupAssocA4L"
483 ${If} $1 == ""
484 ; nothing to restore: delete it
485 DeleteRegKey HKCR ".a4l"
486 ${Else}
487 WriteRegStr HKCR ".a4l" "" $1
488 ${EndIf}
489 DeleteRegValue HKLM "SOFTWARE\ASCEND" "BackupAssocA4L"
490 ${EndIf}
491
492 DeleteRegKey HKCR "ASCEND.model" ;Delete key with association settings
493
494 System::Call 'Shell32::SHChangeNotify(i 0x8000000, i 0, i 0, i 0)'
495 ;rest of script
496
497 unnopython:
498
499 ;--- tcl/tk components ---
500
501 ReadRegDWORD $0 HKLM "SOFTWARE\ASCEND" "TclTk"
502 ${If} $0 != 0
503 DetailPrint "--- REMOVING TCL/TK COMPONENTS ---"
504 Delete $INSTDIR\ascendtcl.dll
505 Delete $INSTDIR\ascend4.exe
506 RMDir /r $INSTDIR\tcltk
507 ${EndIf}
508
509 ;--- documentation ---
510
511 ReadRegDWORD $0 HKLM "SOFTWARE\ASCEND" "PDF"
512 ${If} $0 != 0
513 DetailPrint "--- REMOVING DOCUMENTATION ---"
514 Delete $INSTDIR\book.pdf
515 ${EndIf}
516
517 ;--- start menu ---
518
519 ReadRegDWORD $1 HKLM "SOFTWARE\ASCEND" "StartMenu"
520 IntCmp $1 0 unnostart unstart
521 unstart:
522 ; Remove shortcuts, if any
523 DetailPrint "--- REMOVING START MENU SHORTCUTS ---"
524 RmDir /r "$SMPROGRAMS\ASCEND"
525
526 unnostart:
527
528 ;--- common components ---
529
530 DetailPrint "--- REMOVING COMMON COMPONENTS ---"
531 ; Remove registry keys
532
533 DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\ASCEND"
534 DeleteRegKey HKLM "SOFTWARE\ASCEND"
535
536 ; Remove files and uninstaller
537
538 Delete $INSTDIR\ascend-config
539 Delete $INSTDIR\ascend-config.bat
540 Delete $INSTDIR\ascend.dll
541 Delete $INSTDIR\LICENSE.txt
542 Delete $INSTDIR\README-windows.txt
543 Delete $INSTDIR\CHANGELOG.txt
544 Delete $INSTDIR\ascend.ico
545 Delete $INSTDIR\Makefile.bt
546 Delete $INSTDIR\ascend.syn
547 RMDir /r $INSTDIR\models
548 Delete $INSTDIR\solvers\qrslv.dll
549 Delete $INSTDIR\solvers\conopt.dll
550 Delete $INSTDIR\solvers\lrslv.dll
551 Delete $INSTDIR\solvers\cmslv.dll
552 Delete $INSTDIR\solvers\lsode.dll
553 Delete $INSTDIR\solvers\ida.dll
554
555 ; Remove directories used
556
557 Delete $INSTDIR\uninstall.exe
558 RMDir $INSTDIR
559
560 SectionEnd
561
562 !include "dependencies.nsi"
563
564 !include "detect.nsi"
565
566 !include "ascendini.nsi"

john.pye@anu.edu.au
ViewVC Help
Powered by ViewVC 1.1.22