/[ascend]/trunk/models/johnpye/fprops/pump_exergy.a4c
ViewVC logotype

Contents of /trunk/models/johnpye/fprops/pump_exergy.a4c

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3180 - (show annotations) (download) (as text)
Sat Nov 5 03:50:37 2016 UTC (2 years, 8 months ago) by jpye
File MIME type: text/x-ascend
File size: 2171 byte(s)
added calculation of exergy destruction in a simple pump with accurate fluid properties (liquid water).

1 (*
2 A simple calculation of exergy destruction in a pump, tested with a
3 quasi-incompressible fluid (liquid water).
4
5 Effects due to kinetic energy/velocity changes are ignored. This is reasonable,
6 since the pump inlet/outlet pipes can be whatever we chose.
7 *)
8
9 REQUIRE "johnpye/fprops/rankine_fprops.a4c";
10
11 MODEL pump_exergy;
12 inlet IS_A stream_node;
13 outlet IS_A stream_node;
14
15 PU IS_A pump_simple;
16 mdot ALIASES PU.mdot;
17 inlet, PU.inlet ARE_THE_SAME;
18 outlet, PU.outlet ARE_THE_SAME;
19 cd ALIASES inlet.cd;
20
21 cd.component :== 'water';
22 cd.type :== 'helmholtz';
23
24 ref "exergy reference state" IS_A stream_state;
25 inlet.cd, ref.cd ARE_THE_SAME;
26
27 (* expressions for inlet and outlet flow exergy. fluid velocity ignored. *)
28 X_f_in,X_f_out "flow exergy" IS_A energy_rate;
29 X_f_in_eq: X_f_in = mdot * ( inlet.h - ref.h - ref.T * (inlet.s - ref.s) );
30 X_f_out_eq: X_f_out = mdot * ( outlet.h - ref.h - ref.T * (outlet.s - ref.s) );
31
32 (* exergy balance. assumes adiabatic conditions, neglects KE and PE *)
33 X_d, X_d_2 "exergy destruction" IS_A energy_rate;
34 X_d = X_f_in - X_f_out - PU.Wdot;
35
36 (* another formular for exergy destruction in a pump, obtained using some
37 algebra from the same equations used to calculate X_d; should agree exactly
38 the other value. *)
39 X_d_2 = mdot * (-ref.T*(inlet.s - outlet.s) );
40
41 (* This equation uses assumptions of incompressible fluid and no temperature
42 rise across the pump. It is a fairly good approximation for the current
43 conditions. *)
44 Wdot_2 IS_A energy_rate;
45 Wdot_2 = mdot / PU.eta * inlet.v * (inlet.p - outlet.p);
46
47 (* It turns out the the exergy destruction is quite closely related to the
48 isentropic efficiency -- roughtly Xd = (1-eta)*Wdot, but not exactly. The
49 reason it is not exact appears to be because of ambient conditions. *)
50 F IS_A factor;
51 F = X_d / PU.Wdot;
52
53 METHODS
54 METHOD on_load;
55 RUN PU.default_self;
56 RUN ref.default_self;
57 FIX ref.T := 20 {K} + 273.15 {K};
58 FIX ref.p := 1 {bar};
59
60 FIX PU.eta := 0.65;
61 FIX inlet.T := 30 {K} + 273.15 {K};
62 FIX inlet.p := 1 {bar};
63 FIX outlet.p := 5 {bar};
64 FIX mdot := 200 {kg/s};
65
66 ref.h := 200 {kJ/kg};
67 inlet.h := 200 {kJ/kg};
68 END on_load;
69 END pump_exergy;

john.pye@anu.edu.au
ViewVC Help
Powered by ViewVC 1.1.22